File: DOS.PA of Disk: Disks/PDP8-Net/haygood-osv3r

(Source file text) 

---

/
/	DOS COMMAND
/	EXECUTE ONE DOS COMMAND
/
/	AUTHOR: BILL HAYGOOD
/		41832 ERNEST ROAD
/		LOON LAKE, WA 99148-9607
/		VOICE/FAX: 509-233-2555
/
DOS=6770
LINE=1000
/
	*20
CHAR,	0
/
KEY,	0
	KSF
	JMP	.-1
	KRB
	DCA	CHAR
	TAD	CHAR
	JMP I	KEY
/
OUT,	0
	TSF
	JMP	.-1
	TLS
	CLA
	JMP I	OUT
/
RUBOUT,	0
	CLA
	TAD	[10
	JMS	OUT
	TAD	[40
	JMS	OUT
	TAD	[10
	JMS	OUT
	JMP I	RUBOUT
/
PNTR,	LINE			/ POINTER TO TEXT LINE
/
	*200
MAIN,	SKP			/ ALLOW CHAINING
	JMP	CHAIN
	TLS
LOOP,	JMS	KEY		/ GET A KEY INPUT
	TAD	[-10		/ BACKSPACE ?
	SZA CLA			/ YES
	JMP	MAIN2		/ NO
	JMS	RUBOUT		/ REMOVE IT FROM SCREEN
	STA
	TAD	PNTR		/ AND BACK UP THE POINTER
	DCA	PNTR
	TAD	PNTR
	CIA
	TAD	[LINE
	SMA CLA
	JMP	LOOP		/ GET NEXT KEY
	TAD	[LINE
	DCA	PNTR		/ RESET POINTER
	JMP	LOOP		/ GET NEXT KEY
/
MAIN2,	TAD	CHAR		/ GET THE KEY
	JMS	OUT		/ SHOW IT
	TAD	CHAR		/ STORE CHAR IN TEXT LINE
	AND	[0177
	TAD	[-15
	SNA CLA			/ CARRIAGE RETURN ?
	JMP	MAIN3		/ YES
	TAD	CHAR		/ NO, STORE CHAR IN TEXT LINE
	DCA I	PNTR
	ISZ	PNTR
	JMP	LOOP		/ GET NEXT CHAR
/
MAIN3,	DCA I	PNTR		/ CLEAR LAST LOCATION OF TEXT LINE
/
CHAIN,	TAD	[LINE
	DOS			/ CALL DOS TO EXECUTE COMMAND LINE
	JMP I	[7600		/ RETURN TO OS/8
/
	$

---