File: HELP06.HF of Tape: Sources/Focal/s4
(Source file text)
***** SYMBOLS:
*** ARITHMETIC SYMBOLS:
EXPONENTIATION [^] (INDICATES AN INTEGER EXPONENT)
TYPE 3^2 (OUTPUTS A '9' --- 3 TO THE SECOND POWER)
SET X=Y^Z (SETS X EQUAL TO Y RAISED TO THE INTEGRAL Z POWER)
TYPE 2^3.5 (OUTPUTS AN '8' --- THE .5 IS DROPPED)
MULTIPLICATION [*]
TYPE 2*4 (OUTPUTS AN '8')
SET X=Y*Z (SETS X EQUAL TO Y TIMES Z)
DIVISION [/]
TYPE 6/2 (OUTPUTS A '3')
SET X=Y/Z (SETS X EQUAL TO Y DIVIDED BY Z)
ADDITION [+]
TYPE 2+2 (OUTPUTS A '4')
SET X=Y+Z (SETS X EQUAL TO Y PLUS Z)
SUBTRACTION [-]
TYPE 3-X (OUTPUTS THE VALUE OF 3-X)
SET X=Y-Z (SETS X EQUAL TO Y MINUS Z)
ENCLOSURES (),[], AND <> MAY BE USED INTERCHANGEABLY
IN MATCHED PAIRS TO ENCLOSE QUANTITIES
WHICH ARE TO BE OPERATED ON AS A UNIT.
*** SPECIAL CHARACTERS:
RETURN/LINE FEED [!]
TYPE !!!!,X,!! (OUTPUTS 4 CARRIAGE RETURN/LINE FEEDS,
THE VALUE OF X, AND THEN 2 MORE
CARRIAGE RETURN/LINE FEEDS.
CARRIAGE RETURN [:] OR ^N
SEE WHAT THE ':' DOES IN LINE 10.35
(SEE HOW THE '/' AND THE '\' ARE SUPERIMPOSED)
#10.35 TYPE "X=/",:," \",!!!!!
#D 10.35
X=X
TAB [:X]
SEE WHAT THE ':X' DOES IN LINE 11.37
11.37 TYPE "NAME---":25,"ROGER":40,"AGE = ",2*13,:7,"JONES",!!
NAME---JONES ROGER AGE = 26.0000
OUTPUT FORMATTER [%]
SEE WHAT THE '%' DOES IN LINE 12.30
12.30 SET X=123.456;TYPE %$6.04 X,!;TYPE %*4.02 X,!;T %3.0 X,
!;T %+6,X,!
$ 123.456
*123.5
124.
1.23456E+02
'%4.02' PERMITS FOUR DIGITS TO BE OUTPUT INCLUDING UP TO TWO
DECIMAL PLACES; 'TYPE %' ALONE GIVES POWERS OF TEN NOTATION.
'T %\X' REMOVES THE LEADING SPACE
A NON OPERATOR,TERMINATOR,DIGIT WILL BE USED AS LEADING CHAR
WHEN IMMEDIATELY FOLLOWING THE '%'.
'T %*X' WILL DO A LEFT FILL WITH STARS.
SYMBOL TABLE [$]
TYPE $ (OUTPUTS LIST OF DEFINED VARIABLES)
QUOTATION MARKS ["]
TEXT MAY BE TYPED BY ENCLOSING IT IN QUOTES
SEE WHAT THE '"' DOES IN LINE 14.65
14.65 TYPE "THE ANSWER IS ",3+8,!!!!!
THE ANSWER IS 11.0000
TRACE [?]
THE FIRST TIME FOS8 READS A '?' (EXCEPT WITHIN QUOTES) IT WILL
START OUTPUTTING THE PROGRAM WHILE IT IS EXECUTING IT;THE NEXT
TIME IT ENCOUNTERS A '?' IT WILL STOP TYPING OUT THE PROGRAM.
SEE WHAT THE '?' DOES TO LINE 15.60
15.60 SET X=3;? SET Y=5;TYPE X/Y,!?
SET Y=5;TYPE X/Y, 0.6000!
A 'GO ?' COMMAND WILL TRACE THE ENTIRE PROGRAM.
POWER OF TEN [E]
SEE WHAT THE 'E' DOES TO LINE 6.80
06.80 TYPE 1E1,7E3,1.23E-2,3.76E217,!!!!!
10.0000 7000.00 0.0123 0.376000E+218
RUBOUT KEY
WHEN WRITING A PROGRAM, ONE CHARACTER WILL BE ERASED EACH TIME
THE RUBOUT KEY IS STRUCK; RUBOUT WILL SHOW AS A '\' --- THUS:
'PLWEA\\\EASE' BECOMES 'PLEASE'.
CTRL/C (PRESSING 'CTRL' AND 'C' AT THE SAME TIME)
WILL RETURN USER TO THE OS/8 MONITOR AND CLOSE ALL FILES
-- THE 'LIBRARY EXIT' COMMAND IS KEPT FOR COMPATIBILITY
WITH PS/8 FOCAL,1971. CTRL/P,CTRL/O ARE THE BREAK CHARACTERS.
CTRL/G [BELL] (PRESSING 'CTRL' AND 'G' AT THE SAME TIME)
USED WITH THE 'MODIFY' COMMAND TO CHANGE THE SEARCH CHARACTER.
CTRL/I [TAB] (IS THE HORIZONTAL TAB CODE AND CAN
BE USED IN QUOTED TYPE STATEMENTS)
K (PRESSING 'CTRL' AND 'K' AT THE SAME TIME)
USED WITH 'MODIFY' TO SKIP TO THE NEXT SEARCH CHARACTER.
CTRL/P (PRESSING 'CTRL' AND 'P' AT THE SAME TIME)
CTRL/O (PRESSING 'CTRL' AND 'O' AT THE SAME TIME)
OS/8 FOCAL'S BREAK CHARACTERS --- ENDS PROGRAM EXECUTION
AND CAUSES OS/8 FOCAL TO PRINT ITS '*', OR TO RETURN TO THE KM.
CTRL/Z (PRESSING 'CTRL' AND 'Z' AT THE SAME TIME)
IS THE LAST CHARACTER IN A OS/8 FOCAL DATA FILE. ATTEMPTS TO
READ PAST THE END-OF-FILE WILL CAUSE A '?EF' ERROR TO BE TYPED
ON THE TERMINAL AND WILL RESTORE THE TERMINAL AS THE INPUT
DEVICE.
LINE FEED
USED WITH THE 'MODIFY' COMMAND TO RETAIN REMAINDER OF MODIFIED
LINE.
KILL LINE [_] (BACK ARROW) OR ^U
WHEN WRITING A PROGRAM, '_' OR ^U DELETES EVERYTHING OVER TO
LEFT MARGIN.
IN RESPONSE TO 'ASK' , '_' KILLS THE NUMBER BEING ENTERED.
RETURN KEY
USED WITH THE 'MODIFY' COMMAND TO DELETE REMAINDER OF
MODIFIED LINE.
'RETURN' IS A LEGAL SYMBOL FOR SEPARATING DATA PROVIDED TO
AN 'ASK' COMMAND.
ALT MODE KEY ('ESCAPE' OR 'PREFIX' ON SOME TERMINALS)
IN RESPONSE TO AN 'ASK' COMMAND, ALT MODE RETAINS THE PREVIOUS
VALUE OF THE VARIABLE, AND ECHOES IT IN THE CURRENT FORMAT.
ALSO USED INSTEAD OF RETURN FOR TERMINATING LINE.
SPACE KEY
IT IS A LEGAL SYMBOL FOR SEPARATING DATA REQUESTED BY AN 'ASK'
COMMA [,]
IT IS A LEGAL SYMBOL FOR SEPARATING DATA IN TYPE AND ASK.
SEE WHAT THE ',' DOES TO LINE 26.40:
26.40 TYPE 2,3,5/6,12^3,!!!!
2.0000 3.0000 0.8333 1728.00
SEMICOLON [;]
SEPARATES COMMANDS WHEN PLACED TOGETHER ON ONE LINE
SEE WHAT THE ';' DOES TO LINE 27.42:
27.42 SET X=17;TYPE 3*X;SET X=3/7; TYPE " ",X+3,!!!!
51.0000 3.4286