File: RKCOPY.PA of Tape: Sources/Other/new-16

(Source file text) 

---

/RK05 DISK COPY
/RKCOPY V2.004 3:54 PM 5/20/77
/AUTHORS:	1. JIM DEMPSEY
/		2. DOUG BERGENGREN
/		3. TOM SCHREIER

DSKP=	6741
DCLR=	6742
DLAG=	6743
DLCA=	6744
DRST=	6745
DLDC=	6746
*20
TM,	0

PRINT,	0
	TAD I	PRINT
	DCA	TM
	ISZ	PRINT
PRLP,	TAD I	TM
	BSW
	JMS	PRSUB
	TAD I	TM
	JMS	PRSUB
	ISZ	TM
	JMP	PRLP

PRSUB,	0
	AND	(77
	SNA
	JMP I	PRINT
	TAD	(240
	AND	(77
	TAD	(240
	JMS	TYPE
	JMP I	PRSUB

CRLF,	0
	TAD	(215
	JMS	TYPE
	TAD	(212
	JMS	TYPE
	JMP I	CRLF

TYPE,	0
	TSF
	JMP	.-1
	TLS
	CLA
	JMP I	TYPE

KEY,	0
	KSF
	JMP	.-1
	KRB
	AND	(177
	DCA	TM
	CLA CLL CMA RTL
	TAD	TM
	SNA CLA
	JMP I	(7605
	JMP I	KEY

GDRIVE,	0
	JMS	KEY
	TAD	TM
	JMS	TYPE
	JMS	CRLF
	TAD	TM
	TAD	(-"0+200
	AND	(7774
	SZA CLA
	JMP I	GDRIVE
	ISZ	GDRIVE
	TAD	TM
	TAD	(-"0+200
	CLL RAL
	JMP I	GDRIVE
PAGE
START,	TFL
	JMS	PRINT	/"RK05 DISK COPY V2.???"
	TRKCOP
	JMS	CRLF
ERROR1,	JMS	PRINT	/"FROM DRIVE?"
	TFROM
	JMS	GDRIVE
	JMP	ERROR1
	DCA	DRIVFR
ERROR2,	JMS	PRINT	/"TO DRIVE?"
	TTO
	JMS	GDRIVE
	JMP	ERROR2
	DCA	DRIVTO
	JMS	PRINT	/"STRIKE ANY CHARACTER TO START COPY:"
	TCONT
	JMS	KEY
	JMS	CRLF
COPY,	TAD	DRIVFR	/DRIVE FOR READ
	DCA	DRIVE
LOOP0,	DCA	COMREG
	CLL CMA RAL
	DCA	C1
	DCA	ALL
	TAD	(20
	DCA	FIELDN
LOOP1,	TAD	(-20
	DCA	BLKCNT
	DLCA
LOOP2,	TAD	DRIVE
	TAD	COMREG
	TAD	FIELDN
	TAD	ALL
	TAD	HI
	DLDC
	TAD	SECTOR
	DLAG
	DSKP
	JMP	.-1
	DRST
	CLL RAL
	SZA
	JMP	ERROR
NOERRO,	TAD	(1000
	DCA	ALL
	ISZ	SECTOR
	SKP
	ISZ	HI
	ISZ	BLKCNT
	JMP	LOOP2
	TAD	(30
	DCA	FIELDN
	ISZ	C1
	JMP	LOOP1
	CLL CMA RTL
	DCA	ERRCNT
	TAD	COMREG
	SPA CLA
	JMP	NEXT
	TAD	DRIVTO	/DRIVE FOR WRITE
	DCA	DRIVE
	TAD	SECTOR
	SNA
	DCA	HI
	TAD	(-40
	DCA	SECTOR
	CLA STL RAR
	JMP	LOOP0

NEXT,	ISZ	CYLINDER
	JMP	COPY
	JMS	PRINT
	TDONE
	JMS	CRLF
	JMP I	(7605

ERROR,	AND	(-20-1	/CRC ERROR?
	SZA
	JMP	ERRCOP	/NO
	ISZ	ERRCNT
	SKP
	JMP	NOERROR
	DCA	ALL
	TAD	SECTOR
	AND	(7760
	DCA	SECTOR
	JMP	LOOP1

ERRCOP,	CLA
	JMS	PRINT
	TERR
	JMP I	(7605

DRIVFR,	0	/DRIVE TO READ FROM
DRIVTO,	2	/DRIVE TO WRITE TO (BITS 9-10)
ERRCNT,	-3
DRIVE,	0
COMREG,	0
SECTOR,	0
ALL,	0
FIELDN,	0
HI,	0
C1,	0
BLKCNT,	0
	DECIMAL
CYLINDER,	-203
	OCTAL
PAGE
TRKCOP,	TEXT "RK05 DISK COPY V2.004"
TFROM,	TEXT "FROM DRIVE?"
TTO,	TEXT "TO DRIVE?"
TCONT,	TEXT "STRIKE ANY CHARACTER TO START COPY:"
TDONE,	TEXT "DONE"
TERR,	TEXT "?FATAL ERROR IN COPY"
$

---