File: CCLMSG.MA of Disk: V50/Source/Source-Listing-MAC-1
(Source file text) 

/CCL PRINTING FOR KBM V40
/
/
/
/
/
/
/
/COPYRIGHT  (C)  1979 BY DIGITAL EQUIPMENT CORPORATION
/		 AND 1979 BY DATAPLAN GMBH
/
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/

/2	CCL MESSAGE PRINTER

	.NOLIST
	.INCLUDE OUT:CCLDEF.MA
	.LIST

	.GLOBAL PRWD,PRNAME,PRINT,CRLF,TYPE

	.EXTERNAL TWAIT,BATCH,LEAVE,FATALFLG

	.RSECT CCLMSG

	FIELD 1

	/ALL ROUTINES ARE DATA-FIELD INSENSITIVE
	/AND RESET IT TO 10

PRWD,	0
	DCA	T
	TAD	T
	BSW
	JMS	PCHAR
	TAD	T
	JMS	PCHAR
	JMP I	PRWD

PCHAR,	0
	AND	(77
TNOP,	SNA
	JMP I	PCHAR	/IGNORE NULLS
	TAD	(240
	AND	(77
	TAD	(240
	JMS	TYPE
	JMP I	PCHAR

TE,
PRNAME,	0
	TAD	NAME1
	JMS	PRWD
	TAD	NAME2
	JMS	PRWD
	TAD	NAME3
	JMS	PRWD
	TAD	NAME4
	SNA CLA
	JMP I	PRNAME
	TAD	(256
	JMS	TYPE
	TAD	NAME4
	JMS	PRWD
/	TAD	NAME5
/	SZA
/	JMS	PRWD
	JMP I	PRNAME
TYPE,	0
	CDF 10
	SNA
	JMP I	TYPE	/IGNORE NULLS
	DCA	TE2
	JMS I	(BATCH
	JMP	TTYOUT
	DCA	CIFB
CIFB,	HLT		/REPLACED BY CIF BATCH FIELD
	TAD	TE2
	JMS I	(BATOUT
	TAD	TE2
	TAD	(-"#
	SZA CLA
	JMP I	TYPE
	TAD	CIFB
	IAC		/CONVERT CIF TO CIF CDF
	DCA I	(FATALFLG
	JMP I	TYPE

TTYOUT,	TAD	TE2
	TAD	(-"#	/DON'T TYPE #'S
	SNA CLA
	JMP I	TYPE
KEYTES,	TAD	T7600
	KRS
	TAD	(-7603
	SNA
	JMP I	(LEAVE
	TAD	(203-217	/CTLR O
	SNA
	JMP I	TYPE
	TAD	(217-223	/CTRL S
	SNA CLA
	JMP	CTRLS
	TAD	TE2
TJUMP,	JMP	.+3
	TSF
	JMP	.-1
	TLS
T7600,	7600
	TAD	TNOP
	DCA	TJUMP
	JMP I	TYPE
TE2,	0

CTRLS,	KCC			/WAIT AFTER CTRL S FOR NEXT
	KSF
	JMP	.-1
	JMP	KEYTES
PRINT,	0
	CDF 10
	CLA
	TAD I	PRINT
	ISZ	PRINT
	DCA	TE
1$:	TAD I	TE
	AND	(177
	TAD	(-137
	SNA CLA		/_ AT END MEANS NO CRLF
	JMP I	PRINT
	TAD I	TE
	JMS	TYPE
	TAD I	TE
	ISZ	TE
	AND	(177
	SZA CLA
	JMP	1$
	JMS	CRLF
	JMP I	PRINT

CRLF,	0
	TAD	(215
	JMS	TYPE
	TAD	(212
	JMS	TYPE
	JMP I	CRLF
	PAGE