File: FIUNPK.FT of Tape: Various/System-Tapes/eb-plot

(Source file text) 

---

	SUBROUTINE FIUNPK (ICOM,ARG1,ARG2,IARG3,IARG4)
C	-----------------
C
C  UNPACK DEVICE INDEPENDENT PLOT FILE
C
	DIMENSION	ARG1(1) , ARG2(1) , IARG4(1)
C
	CALL	FIGETB (ICOM)
C  DISPATCH
C
C  MOVE
	IF	(ICOM .GE. 16 .AND. ICOM .LE. 47) GOTO 160
C  CHAR STRING PLOT
	IF	(ICOM .EQ.  5) GOTO  50
C  CHAR SIZE
	IF	(ICOM .EQ.  6) GOTO  60
C  CHAR FONT
	IF	(ICOM .EQ. 52) GOTO 520
C  CHAR STRING PLOT (FONT 0)
	IF	(ICOM .EQ. 86) GOTO 860
C  NEW PEN
	IF	(ICOM .EQ.  4) GOTO  40
C  DEFINE DASH PATTERN
	IF	(ICOM .EQ. 13) GOTO 130
C  NEW PICTURE
	IF	(ICOM .EQ. 53) GOTO 530
C  ALL OTHERS ARE ONE BYTE COMMANDS
	RETURN
C-----------------------------------------------------------------------
C  NEW PEN
C  -------
40	CALL	FIGETB (IARG3)
	RETURN
C-----------------------------------------------------------------------
C  SYMBOL STRING
C  -------------
50	CALL	FIGETB (IARG3)
	DO 54	I = 1,IARG3
	CALL	FIGETB (IB)
54	IARG4(I)= IB + 32
	RETURN
C-----------------------------------------------------------------------
C  SYMBOL SIZE DEFINITION
C  ----------------------
60	DO 61	I = 1,2
	CALL	FIGETB (IB)
61	CALL	FIGETD (IB,ARG1(I),ARG2(I))
	RETURN
C-----------------------------------------------------------------------
C  DASH PATTERN DEFINITION
C  -----------------------
130	CALL	FIGETB (IARG4(1))
	CALL	FIGETB (IARG3)
	DO 133	I = 1,IARG3
	CALL	FIGETB (IB)
133	CALL	FIGETD (IB,ARG1(I),ARG2(I))
	RETURN
C-----------------------------------------------------------------------
C  MOVE
C  ----
160	IB	= ICOM
	ICOM	= 16
	CALL	FIGETD (IB,ARG1(1),ARG2(1))
	RETURN
C-----------------------------------------------------------------------
C  SYMBOL FONT DEFINITION
C  -----------------------
520	CALL	FIGETB (IARG3)
	RETURN
C-----------------------------------------------------------------------
C  START NEW PICTURE
C  -----------------
530	CALL	FIGETB (IB)
	CALL	FIGETD (IB,ARG1(1),ARG2(1))
	RETURN
C-----------------------------------------------------------------------
C  GET SYMBOLS FONT 0
C  ------------------
860	CALL	FIGETB (IARG3)
	DO 861	I = 1,IARG3
	CALL	FIGETB (L)
	CALL	FIGETB (K)
861	IARG4(I)= L*16 + K
	ICOM	= 5
	RETURN
C-----------------------------------------------------------------------
	END

---